mirror of
https://github.com/microsoft/GSL.git
synced 2024-11-03 17:56:43 -05:00
8b320e3f5d
* Refactor cmake file to have GSL as an interface CMake supports header only libraries as INTERFACE libraries. Using interfaces libraries make is easier for users to use the library because one just need to "link" agaisnt the library and necessary include paths, definitions, flags... will be taken care of. This commit creates a new interface library called GSL. It then add the following things to the GSL library: - compiler flags ex: (-std=c++14) - definitions ex: _SCL_SECURE_NO_WARNINGS - include paths ex: include/gsl - natvis file Another project can now have the GSL project as a git submodule and one only need to add the two following lines to their project to use the GSL. add_subdirectory(GSL) target_link_libraries(<some target> GSL) After cmake 3.8.0 a lot of the logic can be simplified. Right now the cmake file has an if for version checking, but when the minimun required version is 3.8.0 one can just delete the branching and keep the simpler version. * Cut support for c++11 Compiling on GCC6.2 with only the c++11 flag will generate compilation errors. For example some of the errors are related to the use of enable_if_t which is a c++14 feature. To avoid compilation errors this comiit removes c++11 support on linux. * Refactor code that pulls unittest-cpp Two minor changes: - uses cmake to find a proper installation of git (in case user does not have it on the path) - checks for the CMakeLists file instead. This is needed for the build itself and seems like a better way to do the checking * Refactor tests so they show together on VS This commit will make a VS geenrated project to group all tests under GSL_tests * Refactor tests configuration This creates a test configuration interface and add all the previous compiler options to that interface. compiler options are now sorted so it is easier to find them, and also one per line, so that modifications are easier to track from git.
55 lines
1.6 KiB
CMake
55 lines
1.6 KiB
CMake
cmake_minimum_required(VERSION 2.8.7)
|
|
|
|
project(GSL CXX)
|
|
|
|
# creates a library GSL which is an interface (header files only)
|
|
add_library(GSL INTERFACE)
|
|
|
|
# when minimum version required is 3.8.0 remove if below
|
|
# both branches do exactly the same thing
|
|
if ( CMAKE_MAJOR_VERSION VERSION_LESS 3.7.9)
|
|
if (NOT MSVC)
|
|
include(CheckCXXCompilerFlag)
|
|
CHECK_CXX_COMPILER_FLAG("-std=c++14" COMPILER_SUPPORTS_CXX14)
|
|
if(COMPILER_SUPPORTS_CXX14)
|
|
target_compile_options(GSL INTERFACE "-std=c++14")
|
|
else()
|
|
message(FATAL_ERROR "The compiler ${CMAKE_CXX_COMPILER} has no C++14 support. Please use a different C++ compiler.")
|
|
endif()
|
|
|
|
endif()
|
|
else ()
|
|
# set the GSL library to be compiled only with c++14
|
|
target_compile_features(GSL INTERFACE cxx_std_14)
|
|
# on *nix systems force the use of -std=c++XX instead of -std=gnu++XX (default)
|
|
set(CMAKE_CXX_EXTENSIONS OFF)
|
|
endif()
|
|
|
|
# add definitions to the library and targets that consume it
|
|
target_compile_definitions(GSL INTERFACE
|
|
$<$<CXX_COMPILER_ID:MSVC>:
|
|
# remove unnecessary warnings about unchecked iterators
|
|
_SCL_SECURE_NO_WARNINGS
|
|
>
|
|
)
|
|
|
|
# add include folders to the library and targets that consume it
|
|
target_include_directories(GSL INTERFACE
|
|
$<BUILD_INTERFACE:
|
|
${CMAKE_CURRENT_SOURCE_DIR}/include
|
|
>
|
|
)
|
|
|
|
# add natvis file to the library so it will automatically be loaded into Visual Studio
|
|
target_sources(GSL INTERFACE
|
|
${CMAKE_CURRENT_SOURCE_DIR}/GSL.natvis
|
|
)
|
|
|
|
install(
|
|
DIRECTORY include/gsl
|
|
DESTINATION include
|
|
)
|
|
|
|
enable_testing()
|
|
add_subdirectory(tests)
|