mirror of
https://github.com/microsoft/GSL.git
synced 2024-11-03 17:56:43 -05:00
8b320e3f5d
* Refactor cmake file to have GSL as an interface CMake supports header only libraries as INTERFACE libraries. Using interfaces libraries make is easier for users to use the library because one just need to "link" agaisnt the library and necessary include paths, definitions, flags... will be taken care of. This commit creates a new interface library called GSL. It then add the following things to the GSL library: - compiler flags ex: (-std=c++14) - definitions ex: _SCL_SECURE_NO_WARNINGS - include paths ex: include/gsl - natvis file Another project can now have the GSL project as a git submodule and one only need to add the two following lines to their project to use the GSL. add_subdirectory(GSL) target_link_libraries(<some target> GSL) After cmake 3.8.0 a lot of the logic can be simplified. Right now the cmake file has an if for version checking, but when the minimun required version is 3.8.0 one can just delete the branching and keep the simpler version. * Cut support for c++11 Compiling on GCC6.2 with only the c++11 flag will generate compilation errors. For example some of the errors are related to the use of enable_if_t which is a c++14 feature. To avoid compilation errors this comiit removes c++11 support on linux. * Refactor code that pulls unittest-cpp Two minor changes: - uses cmake to find a proper installation of git (in case user does not have it on the path) - checks for the CMakeLists file instead. This is needed for the build itself and seems like a better way to do the checking * Refactor tests so they show together on VS This commit will make a VS geenrated project to group all tests under GSL_tests * Refactor tests configuration This creates a test configuration interface and add all the previous compiler options to that interface. compiler options are now sorted so it is easier to find them, and also one per line, so that modifications are easier to track from git.
83 lines
2.0 KiB
CMake
83 lines
2.0 KiB
CMake
cmake_minimum_required(VERSION 2.8.7)
|
|
|
|
project(GSLTests CXX)
|
|
|
|
# will make visual studio generated project group files
|
|
set_property(GLOBAL PROPERTY USE_FOLDERS ON)
|
|
|
|
if (NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/unittest-cpp/CMakeLists.txt)
|
|
find_package(Git)
|
|
execute_process(
|
|
COMMAND ${GIT_EXECUTABLE} submodule update --init
|
|
WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
|
|
)
|
|
endif()
|
|
|
|
add_subdirectory(unittest-cpp)
|
|
|
|
# this interface adds compile options to how the tests are run
|
|
# please try to keep entries ordered =)
|
|
add_library(gsl_tests_config INTERFACE)
|
|
target_compile_options(gsl_tests_config INTERFACE
|
|
$<$<CXX_COMPILER_ID:MSVC>:
|
|
/EHsc
|
|
/W4
|
|
/WX
|
|
>
|
|
$<$<NOT:$<CXX_COMPILER_ID:MSVC>>:
|
|
-fno-strict-aliasing
|
|
-Wall
|
|
-Wcast-align
|
|
-Wconversion
|
|
-Wctor-dtor-privacy
|
|
-Werror
|
|
-Wextra
|
|
-Wno-missing-braces
|
|
-Wnon-virtual-dtor
|
|
-Wold-style-cast
|
|
-Woverloaded-virtual
|
|
-Wpedantic
|
|
-Wshadow
|
|
-Wsign-conversion
|
|
>
|
|
)
|
|
|
|
# set test to include the unittest-cpp headers
|
|
# this shiuld be removed when UnitTest++ has the proper headers
|
|
target_include_directories(gsl_tests_config INTERFACE
|
|
./unittest-cpp
|
|
)
|
|
|
|
# set definitions for tests
|
|
target_compile_definitions(gsl_tests_config INTERFACE
|
|
GSL_THROW_ON_CONTRACT_VIOLATION
|
|
)
|
|
|
|
function(add_gsl_test name)
|
|
add_executable(${name} ${name}.cpp)
|
|
target_link_libraries(${name}
|
|
UnitTest++
|
|
GSL
|
|
gsl_tests_config
|
|
)
|
|
add_test(
|
|
${name}
|
|
${name}
|
|
)
|
|
# group all tests under GSL_tests
|
|
set_property(TARGET ${name} PROPERTY FOLDER "GSL_tests")
|
|
endfunction()
|
|
|
|
add_gsl_test(span_tests)
|
|
add_gsl_test(multi_span_tests)
|
|
add_gsl_test(strided_span_tests)
|
|
add_gsl_test(string_span_tests)
|
|
add_gsl_test(at_tests)
|
|
add_gsl_test(bounds_tests)
|
|
add_gsl_test(notnull_tests)
|
|
add_gsl_test(assertion_tests)
|
|
add_gsl_test(utils_tests)
|
|
add_gsl_test(owner_tests)
|
|
add_gsl_test(byte_tests)
|
|
add_gsl_test(algorithm_tests)
|